.include	"m8def.inc"
;----------------------------------------------------------------------------------------------------------------------------------------------
;----------------------------------------------------------------------------------------------------------------------------------------------
; 	Описание регистров и констант
;----------------------------------------------------------------------------------------------------------------------------------------------
;----------------------------------------------------------------------------------------------------------------------------------------------
.def	tmp0 = r16			;Временный регистр 0
.def	tmpInt = r17		;Временный регистр для обработчика прерываний 

.equ	m5S = 100
;----------------------------------------------------------------------------------------------------------------------------------------------
; 	Описание ячеек озу
;----------------------------------------------------------------------------------------------------------------------------------------------
.equ	RegEncod = 0x60
.equ	Counter = 0x61
;----------------------------------------------------------------------------------------------------------------------------------------------
; 	Сопоставление имен
;----------------------------------------------------------------------------------------------------------------------------------------------
#define En_A  PD2
#define En_B  PD3								
;----------------------------------------------------------------------------------------------------------------------------------------------					
;----------------------------------------------------------------------------------------------------------------------------------------------
;	Вектора прерываний
;----------------------------------------------------------------------------------------------------------------------------------------------
;----------------------------------------------------------------------------------------------------------------------------------------------
.cseg

.org	$0000
			rjmp	Start						;Переход на начало программы (Reset Handler)
.org	INT0addr
			rjmp 	IntEnc 
.org	INT1addr
			rjmp 	IntEnc
.org	OVF0addr
			rjmp 	OVF0 						;Переход на обработчик прерываний  по переполнению Таймера0
;----------------------------------------------------------------------------------------------------------------------------------------------
;----------------------------------------------------------------------------------------------------------------------------------------------
;----------------------------------------------------------------------------------------------------------------------------------------------
.org	0x14									;Устанавливаем адресс обработчиак прерываний после таблицы векторов

;=================================================================================================================================================
;	Обработчик внешних прерывания
;=================================================================================================================================================
IntEnc:
		ldi		tmpInt,~(1<<INT1 | 1<<INT0);     Запрешаем прерывания от кнопок
        out		GICR,tmpInt
        
		in		tmpInt,TIFR
        sbr		tmpInt,1<<TOV0;                  Сбрасываем флаг переполнения таймера
		out		TIFR,tmpInt

		in		tmpInt,TIMSK
		sbr		tmpInt,1<<TOIE0;                 Разрешаем прерывания от таймера 		
		out		TIMSK,tmpInt

		ldi		tmpInt,m5S;
        out		TCNT0,tmpInt 

		reti

;=================================================================================================================================================
;	Обработчик прерывания по переполнению Таймера0
;=================================================================================================================================================
OVF0:
	ldi		tmpInt,1<<INTF1 | 1<<INTF0;         Обнуляем флаги прерываний
	out		GIFR,tmpInt

	ldi		tmpInt,1<<INT1 | 1<<INT0;           Разрешаем прерывания от кнопок
    out		GICR,tmpInt

	in		tmpInt,TIMSK
	cbr		tmpInt,1<<TOIE0;                    Запрешаем прерывания от таймера
	out     TIMSK,tmpInt; 

	clr		tmpInt

	sbic	PIND,En_A
	sbr		tmpInt,1
	sbic	PIND,En_B
	sbr		tmpInt,2

	push	tmp0
	lds		tmp0,RegEncod
	cpse	tmp0,tmpInt
	rjmp	CpCodeEncod
	rjmp	EndInt

CpCodeEncod:
	lsl		tmp0
	lsl		tmp0

	or		tmp0,tmpInt
	andi	tmp0,0b00001111
	sts		RegEncod,tmp0

	lds		tmpInt,Counter

	cpi		tmp0,0b00000010
	breq	IncCounter

	cpi		tmp0,0b00001011
	breq	IncCounter

	cpi		tmp0,0b00001101
	breq	IncCounter

	cpi		tmp0,0b00000100
	breq	IncCounter

	cpi		tmp0,0b00000001
	breq	DecCounter

	cpi		tmp0,0b00000111
	breq	DecCounter

	cpi		tmp0,0b00001110
	breq	DecCounter

	cpi		tmp0,0b00001000
	breq	DecCounter	

	rjmp	EndInt	

IncCounter:
	inc		tmpInt
	rjmp	SeveCounter

DecCounter:
	dec		tmpInt

SeveCounter:
	sts		Counter,tmpInt	
EndInt:
	pop		tmp0
	reti										;Выход из прерывания

;=================================================================================================================================================
;=================================================================================================================================================
;	Настройка мк
;=================================================================================================================================================
;=================================================================================================================================================
Start:
	cli											;Запрет прерываний

	ldi		tmp0,low(RAMEND)					;Устанавливаем вершину стека мл. байт (не обязательно, т.к. в программе не используется стек)		
	out 	SPL,tmp0

	ldi		tmp0,High(RAMEND)					;Устанавливаем вершину стека ст. байт (не обязательно, т.к. в программе не используется стек)		
	out 	SPH,tmp0

	clr		tmp0
    out		DDRB,tmp0
 
 	out		DDRC,tmp0
	
	ldi		tmp0,~(1<<En_A | 1<<En_B);        	Линия А и В на вход
	out		DDRD,tmp0
	
	ldi		tmp0,1<<En_A | 1<<En_B;             Подтягивающие к линиям А и В на вход
	out     PORTD,tmp0 

    ldi		tmp0,0b00000100;                    Предделитель 256
	out		TCCR0,tmp0

	ldi		tmp0,0b00000101;
	out		MCUCR,tmp0

	ldi		tmp0,1<<INT1 | 1<<INT0;             Разрешаем прерывания от кнопок
	out		GICR,tmp0
	ldi		tmp0,1<<INTF1 | 1<<INTF0;        	Обнуляем флаги прерываний
    out		GIFR,tmp0

	sei											;Разрешить прерывания
;=================================================================================================================================================
;	Основной цикл
;=================================================================================================================================================
MainLoop:
	rjmp		MainLoop