Система динстанционного управления (доработка)

[dolmatovva]

10 минут назад, tifaso сказал:

о второй микросхемой почти не касаются друг друга

Это не микросхема, это микроконтроллер, это МОЗГИ ! с программой и памятью, для них надо писать прошивку, в прошивку надо передать номер кнопки. а номер кнопки получить или с первого МК, или с ИК-датчика, в любом случае они касаются.

[Реклама]

Реклама: ООО ТД Промэлектроника, ИНН: 6659197470, Тел: 8 (800) 1000-321

[v1ct0r]

19 минут назад, dolmatovva сказал:

не понимаю смысла рисования этих схем

пока будут импульсы емкость будет заряжена и транзисторы будут открыты, подавая питание на микросхему, после прекращения импульсов микросхема будет отключена, до нажатия следующей кнопки.

пока транзисторы открыты абсолютно без разницы какие серии импульсов получает микросхема, будет включен выбранный на ДУ выход

естественно схема требует наладки и подбора элементов, возможно нужно будет применить мосфеты

 

 

[Реклама]

20% скидка на весь каталог электронных компонентов в ТМ Электроникс!

Акция "Лето ближе - цены ниже", успей сделать выгодные покупки!

Плюс весь апрель действует скидка 10% по промокоду APREL24 + 15% кэшбэк и бесплатная доставка!

Перейти на страницу акции

Реклама: ООО ТМ ЭЛЕКТРОНИКС, ИНН: 7806548420, info@tmelectronics.ru, +7(812)4094849

[tifaso]

@dolmatovva Ну это само собой.

[Реклама]

Выбираем схему BMS для корректной работы литий-железофосфатных (LiFePO4) аккумуляторов

 Обязательным условием долгой и стабильной работы Li-FePO4-аккумуляторов, в том числе и производства EVE Energy, является применение специализированных BMS-микросхем. Литий-железофосфатные АКБ отличаются такими характеристиками, как высокая многократность циклов заряда-разряда, безопасность, возможность быстрой зарядки, устойчивость к буферному режиму работы и приемлемая стоимость. Но для этих АКБ, также как и для других, очень важен контроль процесса заряда и разряда, а специализированных микросхем для этого вида аккумуляторов не так много. Инженеры КОМПЭЛ подготовили список имеющихся микросхем и возможных решений от разных производителей. Подробнее>>

Реклама: АО КОМПЭЛ, ИНН: 7713005406, ОГРН: 1027700032161

[andrusha152]

44 минуты назад, v1ct0r сказал:

вот так будет правильнее

А что это будет? Как то непонятненько написано. А нашёл.

4 часа назад, v1ct0r сказал:

 в приемнике тоже можно попробовать сделать питание на микросхему через ключ, который открывается сигналом с фотоприемника

Вот только ничего не получится. Устройство ИК приёмника изнутри. Без сигнала на выходе 5 вольт. И к тому же для запуска контроллера нужно какое то время. А за это время несколько импульсов потеряются.

[dolmatovva]

@v1ct0r @andrusha152 при условии что пульт постоянно шлёт пачки импульсов, возможно это как то и сработает. Но МК это устройство на порядок сложнее микросхем, и не оценит по существу дергания с питанием.

[tifaso]

Думаю не стоит городить такую обвязку с транзисторами. Это ещё тот костыль получится. Буду решать вопрос второй микросхемой.

[dolmatovva]

у ИК датчика выходной ток 5мА, конденсатор С1 пока не зарядится, все импульсы будет забирать на себя, через которое время откроются транзисторы ? это еще без учета скважности импульсов.

[v1ct0r]

40 минут назад, andrusha152 сказал:

Без сигнала на выходе 5 вольт

в этом случае схема упрощается

понадобится один транзистор вместо двух.

[dolmatovva]

схемы этих ДУ с небольшими описаниями http://radioamator.ru/na-mikrokontrollerakh/skhemy-na-attiny/1796-chetyrekhkomandnaya-sistema-distantsionnogo-upravleniya-na-attiny13 , http://www.joyta.ru/6198-prostaya-16-kanalnaya-sistema-ik-distancionnogo-upravleniya-na-attiny2313/

код приемника 16 каналов

Скрытый текст

 

; Prijimac 16-kanaloveho DO
; kodovani delkou mezery. 
; 1 MHz ATTiny2313A 
; vytvoril: DANYK
; http://danyk.cz

.NOLIST   
.INCLUDE "tn2313Adef.inc"  
.LIST     

.DEF REG=R16		;pracovni registr
.DEF REG2=R17		;pracovni registr 2
.DEF STAV=R18		;registr stavu vstupu
.DEF VYST=R19		;registr vystupu
.DEF VYST_2=R20		;registr predchoziho vystupu 
.DEF PRODLEVA=R21	;prodleva do dalsi reakce
.DEF BITY=R22		;pocitadlo bitu

.EQU SMER=DDRB		;rizeni smeru  
.EQU PORT=PORTB		;port  

.EQU SMER2=DDRD		;rizeni smeru  
.EQU PORT2=PORTD	;port  

.EQU SMER3=DDRA		;rizeni smeru  
.EQU PORT3=PORTA	;port  
.EQU PINY3=PINA		;vstupy
                    
.CSEG				;kodovy segment   

.ORG 0
RJMP START

.ORG OC0Aaddr
RJMP CAS_VYPRSEL

.ORG PCIAaddr
RJMP SIGNAL
	

START:

LDI REG,LOW(RAMEND)
OUT SPL,REG

;nastavi port B
LDI REG,0b11111111
OUT SMER,REG
LDI REG,0b00000000
OUT PORT,REG

;nastavi port D
LDI REG,0b01111111
OUT SMER2,REG
LDI REG,0b00000000
OUT PORT2,REG

;nastavi port A
LDI REG,0b00000001
OUT SMER3,REG
LDI REG,0b00000010
OUT PORT3,REG

; NASTAVENI CASOVACU
LDI	REG,0b00000010 	; nastavi инtaи na nulovani pri dosazeni porovnavane...
OUT	TCCR0A,REG    	; ...hodnoty (tzv. CTC), OC0 nevyuzit
LDI	REG,0b00000011 	; preddeleni 64
OUT	TCCR0B,REG    	; 
LDI	REG,213      	; nastavi porovnavanou hodnotu
OUT	OCR0A,REG     	; 

LDI	REG,0b00000001	; povoli preruseni OCIE0A
OUT	TIMSK,REG    	; 



LDI	REG,0b00001000	; povoli preruseni PCINT1
OUT	GIMSK,REG    	;

LDI	REG,0b00000010	; povoli preruseni PCINT na PA1 (PCINT9)
OUT	PCMSK1,REG    	;

LDI	REG,0b00110000	;povoli uspani (sleep) a nastavi mod power down
OUT	MCUCR,REG

;vypne analog. komparator - neni nikdy vyuzit (setri energii)
LDI	REG,0b10000000	
OUT	ACSR,REG  

SEI

SMYCKA:
SLEEP
RJMP SMYCKA


SIGNAL:
IN STAV,PINY3
COM STAV	;invertuje vstupni signal (prijimac v klidu log1)

;Sestupna hrana
SBRC STAV,1
RJMP NE_10

LDI REG,0
OUT TCNT0,REG

NE_10:

;Nabezna hrana
SBRS STAV,1
RJMP NE_01

IN REG,TCNT0

CPI REG,3		;Prah delky zakmitu / (krбtkйho) pulzu
BRLO ZAKMIT

CPI REG,53		;Prah delky dlouhe mezery / mezery mezi snimky
BRLO NE_KONEC_SNIMKU

RCALL KONTROLA

MOV VYST_2,VYST

NE_KONEC_SNIMKU:

LSL VYST
INC BITY
IN REG,TCNT0
CPI REG,13		;Prah kratke / dlouhe mezery
BRLO KRATKA_M
INC VYST
KRATKA_M:

ZAKMIT:
NE_01:

LDI	REG,0b00100000	;povoli uspani (sleep) a nastavi mod idle
OUT	MCUCR,REG
RETI



CAS_VYPRSEL:

RCALL KONTROLA

CLR VYST
SER VYST_2

CLR PRODLEVA

LDI REG,0
OUT TCNT0,REG

LDI	REG,0b00110000	;povoli uspani (sleep) a nastavi mod power down
OUT	MCUCR,REG
RETI



;kontrola spravnosti prenosu
KONTROLA:
CPI BITY,9		;nesedi-li pocet bitu, zahodi kod
BRNE SPATNE_BITY
CP VYST_2,VYST	;nejsou-li 2 po sobe jdouci kody stejne, nereaguje
BRNE RUZNE_KODY
RCALL PRIJEM
RUZNE_KODY:
CLR BITY
RET
SPATNE_BITY:
CLR VYST
CLR BITY
RET



PRIJEM:

CPI PRODLEVA,0
BREQ PRODLEVA_JE_0
RJMP KONEC_TL
PRODLEVA_JE_0:

MOV REG,VYST
SWAP REG
ANDI REG,0b00001111

MOV REG2,VYST
COM REG2
ANDI REG2,0b00001111

CP REG,REG2
BREQ SHODA
RJMP KONEC_TL
SHODA:

CLR REG2
LDI ZL,LOW(SKOK)
LDI ZH,HIGH(SKOK)
ADD ZL,REG
ADC ZH,REG2
IJMP

SKOK:
RJMP TL0
RJMP TL1
RJMP TL2
RJMP TL3
RJMP TL4
RJMP TL5
RJMP TL6
RJMP TL7
RJMP TL8
RJMP TL9
RJMP TL10
RJMP TL11
RJMP TL12
RJMP TL13
RJMP TL14
RJMP TL15


TL0:
IN REG,PORT
SBRC REG,0
CBI PORT,0
SBRS REG,0
SBI PORT,0
RJMP KONEC_TL

TL1:
IN REG,PORT
SBRC REG,1
CBI PORT,1
SBRS REG,1
SBI PORT,1
RJMP KONEC_TL

TL2:
IN REG,PORT
SBRC REG,2
CBI PORT,2
SBRS REG,2
SBI PORT,2
RJMP KONEC_TL

TL3:
IN REG,PORT
SBRC REG,3
CBI PORT,3
SBRS REG,3
SBI PORT,3
RJMP KONEC_TL

TL4:
IN REG,PORT
SBRC REG,4
CBI PORT,4
SBRS REG,4
SBI PORT,4
RJMP KONEC_TL

TL5:
IN REG,PORT
SBRC REG,5
CBI PORT,5
SBRS REG,5
SBI PORT,5
RJMP KONEC_TL

TL6:
IN REG,PORT
SBRC REG,6
CBI PORT,6
SBRS REG,6
SBI PORT,6
RJMP KONEC_TL

TL7:
IN REG,PORT
SBRC REG,7
CBI PORT,7
SBRS REG,7
SBI PORT,7
RJMP KONEC_TL

TL8:
IN REG,PORT2
SBRC REG,0
CBI PORT2,0
SBRS REG,0
SBI PORT2,0
RJMP KONEC_TL

TL9:
IN REG,PORT2
SBRC REG,1
CBI PORT2,1
SBRS REG,1
SBI PORT2,1
RJMP KONEC_TL

TL10:
IN REG,PORT2
SBRC REG,2
CBI PORT2,2
SBRS REG,2
SBI PORT2,2
RJMP KONEC_TL

TL11:
IN REG,PORT2
SBRC REG,3
CBI PORT2,3
SBRS REG,3
SBI PORT2,3
RJMP KONEC_TL

TL12:
IN REG,PORT2
SBRC REG,4
CBI PORT2,4
SBRS REG,4
SBI PORT2,4
RJMP KONEC_TL

TL13:
IN REG,PORT2
SBRC REG,5
CBI PORT2,5
SBRS REG,5
SBI PORT2,5
RJMP KONEC_TL

TL14:
IN REG,PORT2
SBRC REG,6
CBI PORT2,6
SBRS REG,6
SBI PORT2,6
RJMP KONEC_TL

TL15:
IN REG,PORT3
SBRC REG,0
CBI PORT3,0
SBRS REG,0
SBI PORT3,0
RJMP KONEC_TL

KONEC_TL:
LDI PRODLEVA,1
RET

 

 

 

Скрытый текст

 

код передатчика 16к

; Vysilac DO, 16 kanalu  
; CPU 1 MHz
; f 37 000 Hz
; vytvoril: DANYK
; http://danyk.cz

.NOLIST   
.INCLUDE "tn2313Adef.inc"     
.LIST     


.DEF REG=R16		;pracovni registr
.DEF REG2=R17		;pracovni registr 2
.DEF CYKLY=R18		;pocitadlo cyklu
.DEF CEK=R19		;cekaci registr
.DEF CEK2=R20		;cekaci registr 2

.EQU SMER=DDRB		;rizeni smeru  
.EQU PORT=PORTB		;port  
.EQU PINY=PINB		;vstupy

.EQU SMER2=DDRD		;rizeni smeru  
.EQU PORT2=PORTD	;port  
.EQU PINY2=PIND		;vstupy

.EQU SMER3=DDRA		;rizeni smeru  
.EQU PORT3=PORTA	;port  
.EQU PINY3=PINA		;vstupy
                    
.CSEG				;kodovэ segment   

.ORG 0
RJMP START

.ORG PCIBaddr
RJMP TLACITKO_0_7

.ORG PCIAaddr
RJMP TLACITKO_15

.ORG PCIDaddr
RJMP TLACITKO_8_14

	
START:

LDI REG,LOW(RAMEND)
OUT SPL,REG

;nastavi port B
LDI REG,0b00000000
OUT SMER,REG
LDI REG,0b11111111
OUT PORT,REG

;nastavi port D
LDI REG,0b00000000
OUT SMER2,REG
LDI REG,0b01111111
OUT PORT2,REG

;nastavi port A
LDI REG,0b00000010
OUT SMER3,REG
LDI REG,0b00000001
OUT PORT3,REG


LDI	REG,0b00111000	; povoli preruseni PCINT 
OUT	GIMSK,REG    	;

LDI	REG,0b01111111	; povoli preruseni PCINT 
OUT	PCMSK2,REG    	;

LDI	REG,0b00000001	; povoli preruseni PCINT 
OUT	PCMSK1,REG    	;

LDI	REG,0b11111111	; povoli preruseni PCINT 
OUT	PCMSK,REG    	;


LDI	REG,0b00110000	;povoli uspani (sleep) a nastavi mod power down
OUT	MCUCR,REG

;vypne analog. komparator - neni nikdy vyuzit (setri energii)
LDI	REG,0b10000000	
OUT	ACSR,REG  

;vypne dalsi veci: citace, USI, USART (setri energii)
LDI	REG,0b00001111
OUT	PRR,REG  


SEI

SMYCKA:
SLEEP
RJMP SMYCKA


;Tlacitko 0-7
TLACITKO_0_7:
IN REG2,PINY
;ANDI REG2,0b11111111

CPI REG2,0b01111111
BREQ TL7
CPI REG2,0b10111111
BREQ TL6
CPI REG2,0b11011111
BREQ TL5
CPI REG2,0b11101111
BREQ TL4
CPI REG2,0b11110111
BREQ TL3
CPI REG2,0b11111011
BREQ TL2
CPI REG2,0b11111101
BREQ TL1
CPI REG2,0b11111110
BREQ TL0

LDI REG,0b00000001
OUT PORT3,REG
RETI

;Zakoduje tlacitko 0-7
TL7:
LDI REG2,7
RJMP TL_0_7_ZAKOD
TL6:
LDI REG2,6
RJMP TL_0_7_ZAKOD
TL5:
LDI REG2,5
RJMP TL_0_7_ZAKOD
TL4:
LDI REG2,4
RJMP TL_0_7_ZAKOD
TL3:
LDI REG2,3
RJMP TL_0_7_ZAKOD
TL2:
LDI REG2,2
RJMP TL_0_7_ZAKOD
TL1:
LDI REG2,1
RJMP TL_0_7_ZAKOD
TL0:
LDI REG2,0
RJMP TL_0_7_ZAKOD

TL_0_7_ZAKOD:
RCALL VYSILEJ
RJMP TLACITKO_0_7



;Tlacitko 8-14
TLACITKO_8_14:
IN REG2,PINY2
ANDI REG2,0b01111111

CPI REG2,0b00111111
BREQ TL14
CPI REG2,0b01011111
BREQ TL13
CPI REG2,0b01101111
BREQ TL12
CPI REG2,0b01110111
BREQ TL11
CPI REG2,0b01111011
BREQ TL10
CPI REG2,0b01111101
BREQ TL9
CPI REG2,0b01111110
BREQ TL8

LDI REG,0b00000001
OUT PORT3,REG
RETI

;Zakoduje tlacitko 8-14
TL14:
LDI REG2,14
RJMP TL_8_14_ZAKOD
TL13:
LDI REG2,13
RJMP TL_8_14_ZAKOD
TL12:
LDI REG2,12
RJMP TL_8_14_ZAKOD
TL11:
LDI REG2,11
RJMP TL_8_14_ZAKOD
TL10:
LDI REG2,10
RJMP TL_8_14_ZAKOD
TL9:
LDI REG2,9
RJMP TL_8_14_ZAKOD
TL8:
LDI REG2,8
RJMP TL_8_14_ZAKOD

TL_8_14_ZAKOD:
RCALL VYSILEJ
RJMP TLACITKO_8_14


;Tlacitko 15
TLACITKO_15:
IN REG2,PINY3
ANDI REG2,0b00000001

CPI REG2,0b00000000
BREQ TL15

LDI REG,0b00000001
OUT PORT3,REG
RETI

;Zakoduje tlacitko 15
TL15:
LDI REG2,15
RJMP TL_15_ZAKOD

TL_15_ZAKOD:
RCALL VYSILEJ
RJMP TLACITKO_15




;Vysila s pouzitim inverzniho kontrolniho kodu
;Kodovani delkou mezery
;Zacina se MSB
VYSILEJ:
LDI CYKLY,4
VYSILEJ_DAL:

RCALL KRATKA_1

SBRS REG2,3
RCALL KRATKA_0
SBRC REG2,3
RCALL DLOUHA_0

RCALL KRATKA_1

SBRS REG2,2
RCALL KRATKA_0
SBRC REG2,2
RCALL DLOUHA_0

RCALL KRATKA_1

SBRS REG2,1
RCALL KRATKA_0
SBRC REG2,1
RCALL DLOUHA_0

RCALL KRATKA_1

SBRS REG2,0
RCALL KRATKA_0
SBRC REG2,0
RCALL DLOUHA_0

RCALL KRATKA_1

SBRC REG2,3
RCALL KRATKA_0
SBRS REG2,3
RCALL DLOUHA_0

RCALL KRATKA_1

SBRC REG2,2
RCALL KRATKA_0
SBRS REG2,2
RCALL DLOUHA_0

RCALL KRATKA_1

SBRC REG2,1
RCALL KRATKA_0
SBRS REG2,1
RCALL DLOUHA_0

RCALL KRATKA_1

SBRC REG2,0
RCALL KRATKA_0
SBRS REG2,0
RCALL DLOUHA_0

RCALL KRATKA_1

RCALL DLOUHA_0
RCALL DLOUHA_0
RCALL DLOUHA_0
RCALL DLOUHA_0

DEC CYKLY
BRNE VYSILEJ_DAL
RET


;Krбtkб mezera
KRATKA_0:
LDI CEK,16
CEKEJ_K0:

LDI CEK2,8
CEKEJ_K0A:
DEC CEK2
BRNE CEKEJ_K0A

DEC CEK
BRNE CEKEJ_K0
RET


;Dlouhб mezera
DLOUHA_0:
LDI CEK,64
CEKEJ_D0:

LDI CEK2,8
CEKEJ_D0A:
DEC CEK2
BRNE CEKEJ_D0A

DEC CEK
BRNE CEKEJ_D0
RET


;Krбtkэ impulz
KRATKA_1:
LDI CEK,16
CEKEJ_K1:

LDI REG,0b00000011
OUT PORT3,REG

NOP
LDI CEK2,2
CEKEJ_K1A:
DEC CEK2
BRNE CEKEJ_K1A

LDI REG,0b00000001
OUT PORT3,REG

NOP
LDI CEK2,4
CEKEJ_K1B:
DEC CEK2
BRNE CEKEJ_K1B

DEC CEK
BRNE CEKEJ_K1
RET

 

 

 

 

 

 

Изменено 10 января, 2021 пользователем dolmatovva
--

[v1ct0r]

@dolmatovva

"портянки" с кодом спрячьте в "скрытый текст", а то от модератора по голове получите  

Изменено 10 января, 2021 пользователем v1ct0r

[dolmatovva]

краем глаза пробежался по исходнику приемника, комменты на чешском, но и без переводчика почти понятно,

кажется достаточно закомментировать строку 99 ""COM STAV    ;invertuje vstupni signal (prijimac v klidu log1)"

которая отвечает за инвертирование состояние регистров/каналов. и еще добавить строку с обнулением состояния регистров.

9 минут назад, v1ct0r сказал:

"портянки"

поправил)

[otest]

Вот 4х командный поправил. Проверь.

Rx.hex

[dolmatovva]

@otest  еще, после включения  порта в 1, добавить паузу  на 26-27 миллисекунд, потом уже его обнулить.

[otest]

Проверяйте примерно 30 мсек

Rx30.hex

Изменено 11 января, 2021 пользователем otest

[tifaso]

@otest Данная прошивка не отрабатывает. реакции на выходах микросхемы нет вообще замерил прибором при нажатии кнопок пульта сигнал не проходит, а должно быть кратко временая подача питания.

[otest]

30мсек мультиком не увидишь. Тебе сколько надо по времени.

[tifaso]

@otest Мне нужно просто отловить в дальнейшем сигнал другой микросхемой которая уже будет являться процессором и выполнять нужные действия, а тут на выходе нужно получить как бы имитацию нажатия кнопки.

И можешь сделать ещё 16 командную систему она там по точно такому же принципу собрана.

[otest]

Сначала с этой давай разберёмся.

Если скажешь в цифрах , что нужно получить, то будет проще.

Вот прошивка с задержкой на откл.  примерно 0.7 сек.

Rx700.hex

[tifaso]

Всё таки странное поведение этой прошивки https://yadi.sk/d/yXImWnCXjioRyQ

Вот на видео всё заснял. На выводах подкинуты светодиоды. для ловли реакции.

@otest Хорошо давай разбираться по порядку сначала с поведением. Такого явно не должно быть что на видео получилось.

[otest]

Давай общаться однозначно . Работает, не работает, что не работает.

Цитата

Такого явно не должно быть что на видео получилось.

С какой прошивкой? Вот это не ремарка.

Изменено 12 января, 2021 пользователем otest

[tifaso]

@otest Это с прошивкой Rx30.hex с оригиналом он работает стабильно. Хотя и не в том режиме.

При первом же нажатии на пульте пробивает на светодиод и он уже не выключается.

Изменено 12 января, 2021 пользователем tifaso

[colorad]

08.01.2021 в 20:22, tifaso сказал:

TL14:
IN REG,PORT2
SBI PORT2,6
RJMP KONEC_TL

TL14: ldi REG,64  OUT PORT2,REG   RJMP KONEC_TL  ; то есть 2 в степени 6

TL13: ldi REG,32  OUT PORT2,REG   RJMP KONEC_TL ; то есть 2 в степени 5

TL12: ldi REG,16  OUT PORT2,REG   RJMP KONEC_TL  ; то есть 2 в степени 4

попробуйте так для трех , хотя бы  , кнопок

[tifaso]

С этими исходниками работать не получается Атмел студио выбивает кучу ошибок даже если я ничего не изменяя пытаюсь скомпилировать их.

А как их по нормальному перенести в атмел студио я даже и не знаю. Простая копия кода. Приводит к ошибкам.

Изменено 12 января, 2021 пользователем tifaso

[Dr. West]

Обычно, если проанализировать текст ошибок, можно локализовать и устранить проблему. Для этого они и выводятся.

[colorad]

avr studio 4.19 компилит запросто

отсюда hex попробуйте

DO2313.7z

Изменено 12 января, 2021 пользователем colorad