Подключение Бортового Компьютера К Датчику Абс

neftyanik · 24 апреля, 2009

Как сделать электронный спидометр из бортового компьютера? У меня volkswagen T4 1.9D 1991 года, дизель.

Починили КПП, поставили б/у запчасти где нет привода спидометра.

В результате чего исчез привода троса спидометра ну и пройденного пути соответственно.

Механически могу поставить датчик абс. Можно ли каким образом соединить датчик абс с бортовым

компьютером и сделать верные показания скорости? На генераторе есть вывод W, следовательно

можно и показания тахометра сделать. На новых автомобилях показания спидометра идет от абс, через блок.

Реклама

Реклама: ООО ТД Промэлектроника, ИНН: 6659197470, Тел: 8 (800) 1000-321

**my504** · 24 апреля, 2009

Я,право слово, не понял... Если штатно стоит механический спидометр, то его нужно КРУТИТЬ. Причем тут бортовой компьютер? А менять его на электронный это если дизайн позволит и опять же привод одометра какой?

Не очень понятна диспозиция и намерения...

А спидометр вещь не сложная, только нужно знать передаточное число колесного датчика.

Реклама

20% скидка на весь каталог электронных компонентов в ТМ Электроникс!

Акция "Лето ближе - цены ниже", успей сделать выгодные покупки!

Плюс весь апрель действует скидка 10% по промокоду APREL24 + 15% кэшбэк и бесплатная доставка!

Перейти на страницу акции

Реклама: ООО ТМ ЭЛЕКТРОНИКС, ИНН: 7806548420, info@tmelectronics.ru, +7(812)4094849

neftyanik · 25 апреля, 2009

Дело в том, что штатного спидометра уже нет. Я же написал, что шестерни от которой он приводится, нет. Её туда не поставишь, детали были взяты от донора.

Реклама

Выбираем схему BMS для корректной работы литий-железофосфатных (LiFePO4) аккумуляторов

Обязательным условием долгой и стабильной работы Li-FePO4-аккумуляторов, в том числе и производства EVE Energy, является применение специализированных BMS-микросхем. Литий-железофосфатные АКБ отличаются такими характеристиками, как высокая многократность циклов заряда-разряда, безопасность, возможность быстрой зарядки, устойчивость к буферному режиму работы и приемлемая стоимость. Но для этих АКБ, также как и для других, очень важен контроль процесса заряда и разряда, а специализированных микросхем для этого вида аккумуляторов не так много. Инженеры КОМПЭЛ подготовили список имеющихся микросхем и возможных решений от разных производителей. Подробнее>>

Реклама: АО КОМПЭЛ, ИНН: 7713005406, ОГРН: 1027700032161

neftyanik · 28 апреля, 2009

Вот как мне ответила техподдержка с сайта мультитроникс:

Здравствуйте.

Вы писали 27 апреля 2009 г., 22:19:43:

Так я и пишу, что датчик скорости установить невозможно!!! Нет у меня привода к этому датчику.

Могу гребенку на шрус поставить и датчик абс. Как из сигнала датчика АБС запустить бортовой компьютер?

27.04.09, 10:41, "Тех. поддержка" <support@multitronics.ru>:

Здравствуйте.

Вы писали 24 апреля 2009 г., 12:38:59:

Как сделать электронный спидометр из бортового компьютера? У меня volkswagen T4 1.9D 1991 года.

Починили КПП, поставили б/у запчасти где нет привода спидометра. В результате чего исчез привода

троса спидометра ну и пройденного пути соответственно. Механически могу поставить датчик абс.

Можно ли каким образом соединить датчик абс с бортовым компьютером и сделать верные показания

скорости? На генераторе есть вывод W, следовательно можно и показания тахометра сделать. На новых

автомобилях показания спидометра идет от абс, через блок.

------------------------------------------------------------

Отправитель: Андрей

77.220.51.197

Если подключить МК к датчику скорости, то он будет ее показывать.

--

С уважением,

Служба технической поддержки mailto:support@multitronics.ru

ООО "Мультитроникс" http://www.multitronics.ru

Пожалуйста, не удаляйте предыдущую переписку при ответе.

Благодаря этому мы сможем Вам быстрее ответить.

Мы не автосервис. Все подключения - штатные - описаны в инструкции.

--

С уважением,

Служба технической поддержки mailto:support@multitronics.ru

ООО "Мультитроникс" http://www.multitronics.ru

Пожалуйста, не удаляйте предыдущую переписку при ответе.

Благодаря этому мы сможем Вам быстрее ответить.

**Витала** · 28 апреля, 2009

Если я не ошибаюсь -то Вам необходимо получить на выходе 6 или 10 импульсов -для спидометра (сужу по советским Авто) думаю что необходимо посчитать сколько импульсов даст АВС за один оборот -посчитарь растояние -какое сделает Ваше колесо(в зависимости от размера резины) и можно использовать делители импульсов к примеру собрать этот девайс на 561 серии!

**my504** · 1 мая, 2009

Витала в принципе прав, но практически это не реализуемо в таком виде. Попробуем посчитать. Оборот колеса - приблизительно 2,5...3 метра пробега автомобиля. Значит при 6 импульсах на оборот имеем 1 импульс на полметра. Или 0,55 герца на 1 км/час...

Ну и как тут мерять частоту? В аккурат на скорости 45 км/ч частота получится 25 гц, а период накопления импульсов для получения цифры 45 потребуется почти 2 секунды. Некуртуазно...

Но есть для автора одна информация-предложение. Тут один сибирский товарисч попросил сделать спидометр на свою машину взамен сломанного. Я согласился и практически разработку довел до конца. Но тут у тварисча что то переклинило и он отказался от дальнейшего сотрудничества. Денег за разработку я не просил и не прошу. Саму схему и прошивку, а так же топологию печатной платы могу опубликовать открыто. Схема выполнена на PIC16F630. Одном из самых недорогих МК Микрочипа. Могу быстро переписать код для любого другого ПИКа, но при условии, что число выводов не менее 14. Т.е. на 8 выводов не получится, а остальные можно. Тип индикатора - светодиодный семисегментный трехразрядный. В разработке был использован довольно крупный и мощный, если сократить размер, то можно часть ключей управления упростить или исключить.

Короче, если есть нужда (и не только у автора) материалы немедленно выложу в тему...

neftyanik · 9 мая, 2009

Спасибо за ответы. Схема конечно нужна. Общался с техподдержкой мультисета и мильтитроникса. У них есть вот такие схемы подключения к их продукции. Внутри их продукта есть регулировки. Будет ли такая схема работать?

**kotenok** · 12 июня, 2009

My 504 (Уважаемый Марк) ! Я не отказывался!!! Просто я попросил Вас о возможной починке штатной панели, но Вы отказали, и я предложил продолжить начатую тему, а Вы закрылись, и всё. Даже на мыло не отвечаете!

Изменено 12 июня, 2009 пользователем kotenok

**my504** · 12 июня, 2009

Котенок, начатая тема была завершена и я выкладываю ее результат здесь. Но ничего более делать по данному вопросу я не буду. Во первых нет времени, а во вторых ситуация мне не понравилась (хочу-нехочу)...

Получайте:

Прошивка контроллера:

:020000040000FA
:04000000000035289F
:08000800B0000308B1000B1960
:1000100020288B1828281010F8308F008E0110141B
:1000200002302D0203191E28AD0A2515AE03031D4B
:100030001C280F30AE00A5150C103028AD01152876
:10004000240903192528A40A2628A5140B113028F1
:1000500001088101AB002408A401AC0025148B1019
:1000600031088300B00E300E090085018701703021
:100070008B0007309900103090008316C530810046
:1000800001308C000C30850000308700FF23900089
:100090008312A401AB01AC01AD01A501A3016F2046
:1000A000F0308F008E01810110148B1725195F200D
:1000B000251C5628A51D5628A5116F205628CC3082
:1000C00085052D08203E84000008922087004039D5
:1000D000031D85162D088E20850425110800A30117
:1000E0002C08B03C031D76282B08103C03188128EF
:1000F0002C08FF3C031D7E282B08FE3C0318A30A96
:100100008228C0209E202208031D8C280A3EA200BF
:10011000210803190A3EA1002510080082070134B6
:100120000234103482073F3406345B344F34663473
:100130006D347D3407347F346F340034A201230ED4
:1001400023070F398318163E8318063E063E831C8C
:10015000FA3E231A1B3E831CFA3EA31A303E231B91
:10016000603EA31B203E603EA20D221CA03EA000CC
:10017000A100A10E0F30A005A105A31BA20A080033
:100180000030A7001030A800B030A900A301AA01D8
:100190000A30A6000310A70DA80DA90DAA0D2C0862
:1001A0002A02031DD5282B082902031CDE282B0850
:1001B000A902031CAA032C08AA020314A30DA60B70
:1001C000CA28031CE628A30CA30AE728A30C0800EE
:02400E00843FED
:00000001FF

Исходник на ассемблере:

;**********************************************************************
;	Filename:		Speedometr.asm									*
;	Date:			April, 2009									 *
;	Author:		  Yampolsky Mark								  *
;**********************************************************************
;  1 - Vdd [+5v]
;  2 - RA5 [segG]
;  3 - RA4 [com2]
;  4 - MCLR
;  5 - RC5 [segF]
;  6 - RC4 [segE]
;  7 - RC3 [segD]
;  8 - RC2 [segC]
;  9 - RC1 [segB]
; 10 - RC0 [segA]
; 11 - INT [input-RA2]
; 12 - RA1 [com1]
; 13 - RA0 [com0]
; 14 - Vss [GND]
;**********************************************************************
list		p=16f630
#include	<P16F630.inc>
errorlevel	-302
;**********************************************************************	
__CONFIG   _CP_OFF & _CPD_OFF & _BODEN_OFF & _MCLRE_OFF & _WDT_OFF & _PWRTE_ON & _INTRC_OSC_NOCLKOUT 
;**********************************************************************
w_temp		EQU	0x30
status_temp		EQU	0x31
speed0		EQU	0x20
speed1		EQU	0x21
speed2		EQU	0x22
speed			EQU	0x23
countH		EQU	0x24
flags			EQU	0x25
count_ready		EQU	0
over			EQU	1
displ			EQU	2
t_out			EQU	3
temp			EQU	0x26
d_L			EQU	0x27
d_H			EQU	0x28
d_U			EQU	0x29
c_L			EQU	0x2A
bufL			EQU	0x2B
bufH			EQU	0x2C
digit			EQU	0x2D
timeout		EQU	0x2E
;---------------------------
time_out		EQU	0x0F			; константа .255
;**********************************************************************
ORG		0x000
	nop
	  goto		main
;----------------------------------------------------------------------
ORG		0x004
	movwf		w_temp
	movf		STATUS,w
	movwf		status_temp
;----------
	btfsc		INTCON,T0IF
	goto		T0_int
	btfsc		INTCON,INTF
	goto		ext_int
T1_int	bcf		T1CON,TMR1ON
	movlw		0xF8
	movwf		TMR1H
	clrf		TMR1L
	bsf		T1CON,TMR1ON
	movlw		.2
	subwf		digit,w
	btfsc		STATUS,Z
	goto		max
	incf		digit,f
max_out	bsf		flags,displ
	decf		timeout,f
	btfss		STATUS,Z
	goto		$+4
	movlw		time_out
	movwf		timeout
	bsf		flags,t_out
	bcf		PIR1,TMR1IF
	goto		exit
max		clrf		digit
	goto		max_out
T0_int	comf		countH,w
	btfsc		STATUS,Z
	goto		$+3
	incf		countH,f
	goto		$+2
	bsf		flags,over
	bcf		INTCON,T0IF
	goto		exit
ext_int	movf		TMR0,w
	clrf		TMR0
	movwf		bufL
	movf		countH,w
	clrf		countH
	movwf		bufH
	bsf		flags,count_ready
	bcf		INTCON,INTF
;----------
exit		movf		status_temp,w
	movwf		STATUS
	swapf		w_temp,f
	swapf		w_temp,w
	retfie
;======================================================================
main		clrf		PORTA
	clrf		PORTC
	movlw		b'01110000'
	movwf		INTCON
	movlw		b'00000111'
	movwf		CMCON
	movlw		b'00010000'
	movwf		T1CON
	bsf		STATUS,RP0
	movlw		b'11000101'
	movwf		OPTION_REG
	movlw		b'00000001'
	movwf		PIE1
	movlw		b'00001100'
	movwf		TRISA
	movlw		b'00000000'
	movwf		TRISC
	call		0x3FF
	movwf		OSCCAL
	bcf		STATUS,RP0
	clrf		countH
	clrf		bufL
	clrf		bufH
	clrf		digit
	clrf		flags
	clrf		speed
	call		calc
	movlw		0xF0
	movwf		TMR1H
	clrf		TMR1L
	clrf		TMR0
	bsf		T1CON,TMR1ON
	bsf		INTCON,GIE
;-----------
superloop	btfsc		flags,displ
	call		out_LED
	btfss		flags,count_ready
	goto		superloop
	btfss		flags,t_out
	goto		superloop
	bcf		flags,t_out
	call		calc
	goto		superloop
;======================================================================
out_LED	movlw		b'11001100'
	andwf		PORTA,f
	movf		digit,w
	addlw		speed0
	movwf		FSR
	movf		INDF,w
	call		tab_LED
	movwf		PORTC
	andlw		b'01000000'
	btfss		STATUS,Z
	bsf		PORTA,5
	movf		digit,w
	call		tab_com_LED
	iorwf		PORTA,f
	bcf		flags,displ
	return
;----------------------------------------------------------------------
calc		clrf		speed			;
	movf		bufH,w		;
	sublw		0xB0			;
	btfss		STATUS,Z		;
	goto		$+3			;
	movf		bufL,w		;
	sublw		0x10			;
	btfsc		STATUS,C		;
	goto		contin		;
	movf		bufH,w		;
	sublw		0xFF			;
	btfss		STATUS,Z		;
	goto		$+3			;
	movf		bufL,w		;
	sublw		0xFE			;
	btfsc		STATUS,C		;
	incf		speed,f		;
	goto		$+2			;
contin	call		div24x16		;
	call		bin_BCD		;
	movf		speed2,w		; гашение 2-х первых
	btfss		STATUS,Z		; нулевых разрядов
	goto		$+7
	addlw		0x0A			;
	movwf		speed2		;
	movf		speed1,w		;
	btfsc		STATUS,Z		;
	addlw		0x0A			;
	movwf		speed1		;
	bcf		flags,count_ready	;
	return				;
;----------------------------------------------------------------------
tab_com_LED	addwf		PCL,f
	retlw		b'00000001'		; "0 разр"
	retlw		b'00000010'		; "1 разр"
	retlw		b'00010000'		; "2 разр"
;----------------------------------------------------------------------
tab_LED	addwf		PCL,f
	retlw		b'00111111'		; "0"
	retlw		b'00000110'		; "1"
	retlw		b'01011011'		; "2"
	retlw		b'01001111'		; "3"
	retlw		b'01100110'		; "4"
	retlw		b'01101101'		; "5"
	retlw		b'01111101'		; "6"
	retlw		b'00000111'		; "7"
	retlw		b'01111111'		; "8"
	retlw		b'01101111'		; "9"
	retlw		b'00000000'		; "гашение"
;----------------------------------------------------------------------
bin_BCD	clrf		speed2
	swapf		speed,w
	addwf		speed,w
	andlw		0x0F
	btfsc		STATUS,DC
	addlw		0x16
	btfsc		STATUS,DC
	addlw		0x06
	addlw		0x06
	btfss		STATUS,DC
	addlw		0xFA
	btfsc		speed,4
	addlw		0x1B
	btfss		STATUS,DC
	addlw		0xFA
	btfsc		speed,5
	addlw		0x30
	btfsc		speed,6
	addlw		0x60
	btfsc		speed,7
	addlw		0x20
	addlw		0x60
	rlf		speed2,f
	btfss		speed2,0
	addlw		0xA0
	movwf		speed0
	movwf		speed1
	swapf		speed1,f
	movlw		0x0F
	andwf		speed0,f
	andwf		speed1,f
	btfsc		speed,7
	incf		speed2,f		
	return
;----------------------------------------------------------------------
div24x16	movlw		0x00			; деление 0xB010.0 на период вх.имп.
;		addwf		correct,w		;
	movwf		d_L			;
	movlw		0x10			;
	movwf		d_H			;
	movlw		0xB0			;
	movwf		d_U			;
	clrf		speed		;
	clrf		c_L			;
	movlw		.10			;
	movwf		temp			;
loop_div	bcf		STATUS,C		;
	rlf		d_L,f			;
	rlf		d_H,f			;
	rlf		d_U,f			;
	rlf		c_L,f			;
	movf		bufH,w		;
	subwf		c_L,w			;
	btfss		STATUS,Z		;
	goto		$+3			;
	movf		bufL,w		;
	subwf		d_U,w			;
	btfss		STATUS,C		;
	goto		$+8			;
	movf		bufL,w		;
	subwf		d_U,f			;
	btfss		STATUS,C		;
	decf		c_L,f			;
	movf		bufH,w		;
	subwf		c_L,f			;
	bsf		STATUS,C		;
	rlf		speed,f		;
	decfsz	temp,f		;
	goto		loop_div		;
	btfss		STATUS,C		; досчет и округление
	goto		$+4			;
	rrf		speed,f		;
	incf		speed,f		;
	goto		$+2			;
	rrf		speed,f		;
	return				;
;----------------------------------------------------------------------
END

**kotenok** · 13 июня, 2009

Уважаемый Марк! А какие мосфеты можно использовать, если не секрет, Я занимался только силовыми... И ещё раз у Вас уже есть топология печатки, может и её выложите, а я Вам денег отправлю...

**my504** · 13 июня, 2009

Денег не надо, я за саму разработку денег не беру (если иное не было оговорено ранее, а оно НЕ БЫЛО ОГОВОРЕНО - речь шла лишь о возмещении материальных затрат).

МОСФЕТы применены в корпусе sot23 - например IRLML2402(IRLML2502), но можно и любые другие, даже возможна замена на биполярные, но с делителями в базе.

Печатка в pdf-формате под ЛУТ(обратная сторона, прямая - сплошная металлизация - переходные отверстия на нее - это земля, вокруг выводов МК и корпусных элементов зенковка, чтобы исключить контакт с металлизацией). Расположение элементов и внешний вид в виде скрина из PCAD позже, не готовы скрины и нет безлимита на перекачку больших файлов - только вечером:

PCB_autospeed.pdf

**kotenok** · 13 июня, 2009

Многоуважаемый Марк! Я тут сейчас ознакомился с одной ссылочкой, искал МК- но в ценах так ине понял- в одном месте такие МК тогуют за 200 рублей, а в другом за 24 рубля...В одном месте транзисторы означенные вами стоят от 32-х руб., а в другом от 4-х. Как это понимать? http://progcode.narod.ru/project/auto_scor.html И взглянитет на эту ссылочку. Просто программатор на неё проще сделать? (простой-JDM)

**my504** · 13 июня, 2009

630-ый стоит у практически официального поставщика (Тритон электроникс) в розницу около 50 руб. Транзисторы в Терраэлектронике около 5 рублей. Программатор сейчас (PICKit2) торгуют по 600 рублей...

**my504** · 14 июня, 2009

Как обещал.

Вид со стороны поверхностного монтажа(МК на обратной стороне) и обратная сторона на просвет со стороны поверхностного монтажа. Металлизация зеленая (обратная сторона). Проводники разводки красные(прямая сторона, распайка транзисторов и резисторов):

**kotenok** · 15 июня, 2009

Уважаемый Марк! Спасибо большое! А 630-й можно программировать JDM-программатором? И меня ещё шибко смущает, что все элементы SMD. Они продаются только рулонами.

**ELEKTRO-X** · 17 ноября, 2010

Витала в принципе прав, но практически это не реализуемо в таком виде. Попробуем посчитать. Оборот колеса - приблизительно 2,5...3 метра пробега автомобиля. Значит при 6 импульсах на оборот имеем 1 импульс на полметра. Или 0,55 герца на 1 км/час...

Ну и как тут мерять частоту? В аккурат на скорости 45 км/ч частота получится 25 гц, а период накопления импульсов для получения цифры 45 потребуется почти 2 секунды. Некуртуазно...

Но есть для автора одна информация-предложение. Тут один сибирский товарисч попросил сделать спидометр на свою машину взамен сломанного. Я согласился и практически разработку довел до конца. Но тут у тварисча что то переклинило и он отказался от дальнейшего сотрудничества. Денег за разработку я не просил и не прошу. Саму схему и прошивку, а так же топологию печатной платы могу опубликовать открыто. Схема выполнена на PIC16F630. Одном из самых недорогих МК Микрочипа. Могу быстро переписать код для любого другого ПИКа, но при условии, что число выводов не менее 14. Т.е. на 8 выводов не получится, а остальные можно. Тип индикатора - светодиодный семисегментный трехразрядный. В разработке был использован довольно крупный и мощный, если сократить размер, то можно часть ключей управления упростить или исключить.

Короче, если есть нужда (и не только у автора) материалы немедленно выложу в тему...

ДОБРОГО ЗДРАВИЯ ВАМ! а сгодится ли эта схема для 2108 и как её подключать? спасибо!

**my504** · 17 ноября, 2010

Схема то сгодится. А вот прошивку нужно корректировать.

Я даже не знаю, сохранился ли исходник, дело было полтора года назад.

Дома посмотрю на ноуте...

Войти

Подключение Бортового Компьютера К Датчику Абс

Рекомендуемые сообщения

Ссылка на комментарий

Поделиться на другие сайты

Ссылка на комментарий

Поделиться на другие сайты

Ссылка на комментарий

Поделиться на другие сайты

Ссылка на комментарий

Поделиться на другие сайты

Ссылка на комментарий

Поделиться на другие сайты

Ссылка на комментарий

Поделиться на другие сайты

Ссылка на комментарий

Поделиться на другие сайты

Ссылка на комментарий

Поделиться на другие сайты

Ссылка на комментарий

Поделиться на другие сайты

Ссылка на комментарий

Поделиться на другие сайты

Ссылка на комментарий

Поделиться на другие сайты

Ссылка на комментарий

Поделиться на другие сайты

Ссылка на комментарий

Поделиться на другие сайты

Ссылка на комментарий

Поделиться на другие сайты

Ссылка на комментарий

Поделиться на другие сайты

Ссылка на комментарий

Поделиться на другие сайты

Ссылка на комментарий

Поделиться на другие сайты

Присоединяйтесь к обсуждению

Последние посетители 0 пользователей онлайн

Сообщения