Обработка Нажатия Кнопок

[Alex]

почему 65565 операций будут выполняться 65565мкС ?

Потому, что 1 операция выполняется за 1 микросекунду

А сколько времени будут выполняться 65565 операция на частоте 20МГц ?

В 5 раз меньше.

[Реклама]

Реклама: ООО ТД Промэлектроника, ИНН: 6659197470, Тел: 8 (800) 1000-321

[metallic]

почему 65565 операций будут выполняться 65565мкС ?

Потому, что 1 операция выполняется за 1 микросекунду

Я спрашивал почему 1 операция выполняется 1мкС, но уже понял, что миллион мкС разделить на кол-во операций

Ну и на текущий момент по таймеру0 остался один вопрос:

Таймер всегда начинает инкрементироваться с 256 и до 0 или можно задать, чтобы он всегда индкрементировался с произвольной цифры? Например, чтобы точнее задать интервал, можно ли чтобы таймер всегда отсчитывал с 240? Не нашел об этом в даташите.

[Реклама]

20% скидка на весь каталог электронных компонентов в ТМ Электроникс!

Акция "Лето ближе - цены ниже", успей сделать выгодные покупки!

Плюс весь апрель действует скидка 10% по промокоду APREL24 + 15% кэшбэк и бесплатная доставка!

Перейти на страницу акции

Реклама: ООО ТМ ЭЛЕКТРОНИКС, ИНН: 7806548420, info@tmelectronics.ru, +7(812)4094849

[Alex]

Можно. Просто устанавливайте его на любое удобное значение, и он начнёт тикать от этого значения.

При переходе с 255 к 0, установится флаг, и, если разрешено от него прерывание, программа перейдёт на вектор прерываний.

[Реклама]

Особенности хранения литиевых аккумуляторов и батареек

Потеря емкости аккумулятора напрямую зависит от условий хранения и эксплуатации. При неправильном хранении даже самый лучший литиевый источник тока с превосходными характеристиками может не оправдать ожиданий. Технология, основанная на рекомендациях таких известных производителей литиевых источников тока, как компании FANSO и EVE Energy, поможет организовать правильный процесс хранения батареек и аккумуляторов. Подробнее>>

Реклама: АО КОМПЭЛ, ИНН: 7713005406, ОГРН: 1027700032161

[metallic]

Можно. Просто устанавливайте его на любое удобное значение, и он начнёт тикать от этого значения.

При переходе с 255 к 0, установится флаг, и, если разрешено от него прерывание, программа перейдёт на вектор прерываний.

Установлю 240, к примеру. А при следующем цикле таймера он "запомнит", что его в 240 установили или новый цикл начнет с 255 ?

[Реклама]

Выбираем схему BMS для корректной работы литий-железофосфатных (LiFePO4) аккумуляторов

 Обязательным условием долгой и стабильной работы Li-FePO4-аккумуляторов, в том числе и производства EVE Energy, является применение специализированных BMS-микросхем. Литий-железофосфатные АКБ отличаются такими характеристиками, как высокая многократность циклов заряда-разряда, безопасность, возможность быстрой зарядки, устойчивость к буферному режиму работы и приемлемая стоимость. Но для этих АКБ, также как и для других, очень важен контроль процесса заряда и разряда, а специализированных микросхем для этого вида аккумуляторов не так много. Инженеры КОМПЭЛ подготовили список имеющихся микросхем и возможных решений от разных производителей. Подробнее>>

Реклама: АО КОМПЭЛ, ИНН: 7713005406, ОГРН: 1027700032161

[Alex]

Нет, не запомнит. Начнёт с нуля и до 255. И так по кругу...

Просто в любой момент его можно изменить.

[metallic]

Нет, не запомнит. Начнёт с нуля и до 255. И так по кругу...

Просто в любой момент его можно изменить.

Т.е. просто в обработчик прерывания таймера вставить код, который перед выходом будет устанавливать таймер в нужное положение?

[Alex]

Да. Можно его, после переполнения, предустанавливать на любое значение. Это если Вы хотите получить периоды, меньше полного переполнения таймера.

[metallic]

Да. Можно его, после переполнения, предустанавливать на любое значение. Это если Вы хотите получить периоды, меньше полного переполнения таймера.

Но тут может быть не точность. Например на время записи в EEPROM прерывания отключают, а это значит, что в этот момент таймер может "дойти до кондиции", прерывание таймера не будет обработано и он начнет новый цикл с 255 до 0 ?

[Alex]

Хорошие вопросы задаёте - по существу

Но мы же, по мимо записи, можем таймер ещё и читать. А это значит, что можем корректировать записываемое значение, компенсируя пройденное время после переполнения.

[metallic]

Хорошие вопросы задаёте - по существу

Но мы же, по мимо записи, можем таймер ещё и читать. А это значит, что можем корректировать записываемое значение, компенсируя пройденное время после переполнения.

Понятно, по таймеру0 более-мение в голове уложилось, буду читать дальше

[Alex]

Если Вы взяли ДШ на этот чип только для изучения (не имея его в наличии), то лучше возьмите доку на 16F628A и по нему учите. 84-ый - дорогой и бестолковый "динозавр"

[metallic]

Если Вы взяли ДШ на этот чип только для изучения (не имея его в наличии), то лучше возьмите доку на 16F628A и по нему учите. 84-ый - дорогой и бестолковый "динозавр"

84А я купил почти в одно время с книгой, т.к. в книге все на его примере. То, что он динозавр и дорогой понял чуть позже. Но раз он уже есть, пока ставлю изуверские эксперементы на нем. А так в принципе, какая разница на чем учиться, 628A - тоже самое, как я понимаю, только памяти и переферии побольше.

Изменено 27 октября, 2012 пользователем metallic

[Alex]

Правильно понимаете.

Ну если он есть в наличии, то мучайте его. Для начала изучения пойдёт

[fuckir]

metallic да и значения таймера и другие тайминги программного кода при различных значениях кварца можно определить и настроить в симуляторе (МПлаб)

[metallic]

metallic да и значения таймера и другие тайминги программного кода при различных значениях кварца можно определить и настроить в симуляторе (МПлаб)

У меня мплаб Х, где там?

[metallic]

Почитал про прерывания при изменении уровня порта. В моем случае у контроллера 16F84A генерятся прерывания при изменении уровней на портах RB7:RB4.

Судя по даташиту:

RBIE: RB Port Change Interrupt Enable bit

1 = Enables the RB port change interrupt

0 = Disables the RB port change interrupt

RBIF: RB Port Change Interrupt Flag bit

1 = At least one of the RB7:RB4 pins changed state (must be cleared in software)

0 = None of the RB7:RB4 pins have changed state

Включаются эти прерывания битом RBIE, а при возникновении прерывания устанавливается бит RBIF.

Накидал простенький тестовый пример, работает наполовину. Т.е. прерывание срабатывает, но уходит в бесконечный цикл.

Обработчик прерывания зажигает светодиод и сбасывает бит RBIF, но сетодиод вместо того, чтобы зажечься начинает моргать с максимальной скоростью, как буд-то постоянно возникает прерывание. Не пойму в чем дело, ведь я сбрасываю бит RBIF.

В приложении схема и ниже код.

#include "P16F84.INC"

INTE    equ 4       ; Бит маски(включения) внешнего прерывания(4 бит)
GIE     equ 7       ; Бит глобального разрешения прерываний
RBIF    equ 0       ; Этот бит устанавливается, когда происходит interrupt-on-change
RBIE    equ 3       ; Бит включения interrupt-on-change
RP0     equ 5       ; Бит регистра STATUS для переключения банков памяти

; Вектор сброса контроллера ----------------------------------------------------
       org 000     ; При старте контроллера (адрес программы 000)
       goto MAIN   ; перейти к метке MAIN

; Вектор прерывания ------------------------------------------------------------
       org 004             ; При возникновении прерывания (переход к адресу 004)
       goto IRQ_PROCESS    ; перейти к метке IRQ_PROCESS

; Фоновая программа начинается с инициализации ---------------------------------
MAIN    
       bsf     INTCON, GIE     ; Разрешаем прерывания
       bsf     INTCON, RBIE    ; Разрешаем interrupt-on-change
       bsf     STATUS, RP0     ; Выбираем первый банк памяти
       movlw   b'00000'        ; Конфигурируем 2 как выход, а остальные
       movwf   TRISA           ; контакты как входы у порта A
       bcf     STATUS, RP0     ; Возвращаемся к нулевому банку памяти

       movlw   b'00000'        ; Выставляем низкий уровень на всех
       movwf   PORTA           ; пяти пинах порта А        

; Бесконечный пустой цикл
M_LOOP
       nop             ; Ничего не делаем
       goto M_LOOP

IRQ_PROCESS

       bcf     INTCON, RBIF    ; Сбрасываем флаг внешнего прерывания, чтобы
                               ; не получился бесконечный цикл

       movf    PORTA, w        ; Считываем порт А в рабочий регистр
       xorlw   b'00001'     ; и по маске изменяем нужный пин
       movwf   PORTA           ; Записываем изменения в порт А

       retfie              ; И возврат из прерывания в программу

end

[IMXO]

IRQ_PROCESS
 btfsc INTCON,RBIE
 btfss INTCON, RBIF
	 goto IRQ_end
		 bcf INTCON, RBIF ; Сбрасываем флаг внешнего прерывания, чтобы
									 ; не получился бесконечный цикл

		 movf PORTA, w ; Считываем порт А в рабочий регистр
		 xorlw b'00001' ; и по маске изменяем нужный пин
		 movwf PORTA ; Записываем изменения в порт А
IRQ_end
		 retfie ; И возврат из прерывания в программу

end

[Alex]

Читаем. А конкретно - http://www.microchip.ru/files/d-sheets-rus/pic16_9.pdf . Ещё конкретнее - стр.9

[rmatveev]

А почему никто автору не скажет, что у него нет токоограничивающего резистора в цепи светодиода? Ничего, наверно, не сгорит, но это ИМХО категорически не правильно. Да и кнопка со светодиодом на схеме изображены ИМХО кривовато - +питания внизу, GND вверху. Рисуйте понятнее, а то потом сами же будете путаться с полярностями сигналов

[metallic]

IRQ_PROCESS
 btfsc INTCON,RBIE
 btfss INTCON, RBIF
	 goto IRQ_end
		 bcf INTCON, RBIF ; Сбрасываем флаг внешнего прерывания, чтобы
									 ; не получился бесконечный цикл

		 movf PORTA, w ; Считываем порт А в рабочий регистр
		 xorlw b'00001' ; и по маске изменяем нужный пин
		 movwf PORTA ; Записываем изменения в порт А
IRQ_end
		 retfie ; И возврат из прерывания в программу

end

Тоже самое с таким кодом - светодиод судорожно моргает.

Читаем. А конкретно - http://www.microchip...rus/pic16_9.pdf . Ещё конкретнее - стр.9

Спасибо, получается, как я понял, надо перед сбросом бита RBIF сначала прочесть или написать в порт Б ?

Вот с таким кодом у меня работает с некоторыми оговорками:

IRQ_PROCESS
       movf    PORTB, w
       bcf     INTCON, RBIF

       movf    PORTA, w
       xorlw   b'00001'
       movwf   PORTA

       retfie

Т.е. добавилось чтение порта Б (movf PORTB, w)

Работает теперь так: при первом нажатии сетодиод зажигается, т.е. все как задумано, при повторном нажатии на кнопку срабатывает два прерывания, на нажатие кнопки и отпускание, т.е. при нажатии светодиод тухнет, при отпускании снова загорается, так и должно быть?

[Alex]

Ну так он же изменение ловит. Как с единицы в ноль, так и обратно.

[metallic]

Ну вроде как все заработало, собрал тестовую схему с тремя кнопками(см. скрин).

Вот код:

#include "P16F84.INC"

STATUS  equ 3       ; Регистр STATUS
INTCON  equ h'0B'   ; Регистр управления прерываниями
INTF    equ 1       ; Флаг внешнего прерывания (бит 1)
INTE    equ 4       ; Бит маски(включения) внешнего прерывания(4 бит)
GIE     equ 7       ; Бит глобального разрешения прерываний
RBIF    equ 0       ; Этот бит устанавливается, когда происходит interrupt-on-change
RBIE    equ 3       ; Бит включения interrupt-on-change
RP0     equ 5       ; Бит регистра STATUS для переключения банков памяти
RA0     equ 0       ; Контакт 0 порта А
RA1     equ 1
RA2     equ 2
RB4     equ 4       
RB5     equ 5
RB6     equ 6
PORTA   equ h'05'   ; Порт А
TRISA   equ h'85'   ; Конфиг порта А (первый банк памяти)

_work   equ h'4E'
_status equ h'4F'   ;

; Вектор сброса контроллера ----------------------------------------------------
       org 000     ; При старте контроллера (адрес программы 000)
       goto MAIN   ; перейти к метке MAIN

; Вектор прерывания ------------------------------------------------------------
       org 004             ; При возникновении прерывания (переход к адресу 004)
       goto IRQ_PROCESS    ; перейти к метке IRQ_PROCESS

; Фоновая программа начинается с инициализации ---------------------------------
MAIN    bsf     INTCON, INTE    ; Разрешаем внешнее прерывание (на порту INT/RB0)
       bsf     INTCON, GIE     ; Разрешаем прерывания
       bsf     INTCON, RBIE    ; Разрешаем прерывания на портах RB7:RB4
       bsf     STATUS, RP0     ; Выбираем первый банк памяти
       movlw   b'00000000'     ; Конфигурируем 2 как выход, а остальные
       movwf   TRISA           ; контакты как входы у порта A
       movlw   b'11110000'     ; Порты RB7:RB4 как входы
       movwf   TRISB
       bcf     STATUS, RP0     ; Возвращаемся к нулевому банку памяти

       movlw   b'00000'        ; Выставляем низкий уровень на всех
       movwf   PORTA           ; пяти пинах порта А        

; Бесконечный пустой цикл
M_LOOP
       nop             ; Ничего не делаем
       goto M_LOOP

IRQ_PROCESS
       ; Сохраняем контекст
       movwf   _work       ; Сохраняем рабочий регистр в памяти данных
       swapf   STATUS, w   ; Считываем регистр STATUS в рабочий регистр не меняя флагов
       movwf   _status     ; И сохраняем его из рабочего регистра в память данных

       ; В зависимости от порта, на котором возникло прерывания, вызываем
       ; соответствующую подпрограмму (проверяем по низкому уровню, т.е. нажатие кнопки)
       btfss   PORTB, RB4
        call    IRQ_RB4
       btfss   PORTB, RB5
        call    IRQ_RB5
       btfss   PORTB, RB6
        call    IRQ_RB6

       ; Восстанавливаем контекст
       swapf   _status, w  ; Сначала восстанавливаем
       movwf   STATUS      ; регистр STATUS
       swapf   _work, f    ; Затем рабочий регистр
       swapf   _work, w    ; не воздействуя на флаги регистра STATUS

       ; Чтобы сбросить бит RBIF обязательно надо вначале прочитать порт B
       movf    PORTB, w        ; Сбрасываем флаг внешнего прерывания, чтобы
       bcf     INTCON, RBIF    ; не получился бесконечный цикл

       retfie              ; И возврат из прерывания в программу

IRQ_RB4
       ; Изменяем уровень 17-го пина на вротивоположный с помощью операции
       ; исключающей ИЛИ, т.е. там, где в маске стоят 1, значение 1 изменится
       ; на 0 и наоборот, значение 0 изменится на 1
       movf    PORTA, w        ; Считываем порт А в рабочий регистр
       xorlw   b'00001'        ; и по маске изменяем нужный пин
       movwf   PORTA           ; Записываем изменения в порт А

       return

IRQ_RB5
       movf    PORTA, w
       xorlw   b'00010'
       movwf   PORTA

       return

IRQ_RB6
       movf    PORTA, w
       xorlw   b'00100'
       movwf   PORTA

       return

end

Осталось две непонятности:

1. В чем принципиальная разница прерываний RB0(INT) и RB7:RB4

2. Зачем нужно читать порт B, перед сбросом бита RBIF, в доке написано "для исключения не соответствия", но мне не понятно о чем идет речь.

[Alex]

1. Прерывания по INT происходит только при одном перепаде - либо с 1 в 0, либо наоборот. А на RB4:7 при любом изменении.

2. Несоответствие имеется в виду разница между его значением при предыдущем чтении и текущем его значением. По этому, на каждой команде, будет это несоответствие и будет постоянно устанавливаться флаг, который сбрасывать бесполезно, пока не прочитаешь порт и не уберёшь это несоответствие.

[metallic]

2. Несоответствие имеется в виду разница между его значением при предыдущем чтении и текущем его значением. По этому, на каждой команде, будет это несоответствие и будет постоянно устанавливаться флаг, который сбрасывать бесполезно, пока не прочитаешь порт и не уберёшь это несоответствие.

А почему после чтения порта несоответствие перестает проявляться?

[Alex]

Потому, что несоответствие считается между последним чтением и текущим значением порта. После чтения, соответственно, этой разницы не будет и флаг уже устанавливаться не будет.