Перейти к содержанию

Реле Времени

draf

Автор draf,
в Начинающим

 Поделиться

Рекомендуемые сообщения

Реклама: ООО ТД Промэлектроника, ИНН: 6659197470, Тел: 8 (800) 1000-321

  • Ответов 54
  • Создана
  • Последний ответ

Топ авторов темы

Топ авторов темы

Изображения в теме

my504 Наставник

my504

Опубликовано
Опубликовано

Любезный draf! Не возьмите за труд, очень внятно описать Вашу задачу включая ее полное назначение, но мне в личку. Я подумаю, может и выдам Вам в кратчайшие сроки готовое решение (схему и полное описание реализации). Так же напишите Вашу дислокацию - чтобы знать возможности настоящей реализации в железе...

0

戦う前に相手のベルトの色に注目

Ссылка на комментарий
Поделиться на другие сайты
  • 3 недели спустя...

20% скидка на весь каталог электронных компонентов в ТМ Электроникс!

Акция "Лето ближе - цены ниже", успей сделать выгодные покупки!

Плюс весь апрель действует скидка 10% по промокоду APREL24 + 15% кэшбэк и бесплатная доставка!

Перейти на страницу акции

Реклама: ООО ТМ ЭЛЕКТРОНИКС, ИНН: 7806548420, info@tmelectronics.ru, +7(812)4094849

my504 Наставник

my504

Опубликовано
Опубликовано (изменено)

В связи с завершением изготовления устройства стоит вероятно опубликовать схему, листинг АСМа и прошивку, дабы желающие могли повторить эту конструкцию.

Параметры реле времени для контактной сварки (а так же для любого другого сетевого устройства с симисторным управлением).

1. Диапазон регулировки времени импульса: 0,1...3,0 сек дискретами через 0,1 сек

2. Управление пуском - кнопка

3. Привязка запуска интервала к переходу сетевого напряжения через ноль.

4. Питание - 10...12 вольт переменного напряжения с пиковым потреблением 100 ма

5. Элементная база - МК PIC12F675

Принципиальная схема:

ca529a5a33dd.jpg

Диодный мост любой в DIP корпусе. Стабилитрон стеклянный на 5,1...4,3 вольта. Диод - 1N4148 (КД521)

Максимальный ток оптрона 80 ма, для уменьшения необходимо последовательно включить балластный резистор соответствующего номинала.

Прошивка контроллера (хекс):

:020000040000FA
:0400000000006A286A
:08000800A5000308A6000B1976
:100010001F2840301905031D1D2820084A20A10073
:100020001930FF3E031D112820082A2081000515E4
:100030000B118B1683168C1183128C112528A10BA2
:1000400024280511A4108B120B1126088300A50E7D
:10005000250E09008A018207E634CB34B134963488
:100060007C34613447342C341234F734DD34C234F8
:10007000A8348D34733458343E3423340934EE3488
:10008000D434B9349F3484346A344F3435341A3418
:100090000034E5348A01820707340D3413341934EF
:1000A0001F3425342B34313437343E3444344A340D
:1000B000503456345C34623468346E3474347B3477
:1000C000813487348D34933499349F34A534AB34E0
:1000D000B134B834A001A101A201A301A4018B0194
:1000E0001E309900850183168C013B30850020303D
:1000F00095001B309F00FF239000A1309900053030
:100100008100831205309F000B179F15000000002F
:1001100000000000000000000000000000000000DF
:100120009F149F189128E520A0009F110000000057
:1001300000000000000000000000000000000000BF
:100140009F149F18A128C020A007851A852824186D
:10015000B3282414A41499088C1183168C158312C7
:100160008B17A418B128851EB3280E30A200A30156
:10017000A30BB828A20BB728851EB5282410852804
:10018000F7301E0203180934E6301E020318083443
:10019000D5301E0203180734C4301E02031806347B
:1001A000B3301E0203180534A2301E0203180434B3
:1001B00091301E020318033480301E0203180234EB
:1001C0006F301E0203180134003480301E02031801
:0C01D00014346F301E0203180A3400348F
:02400E00A43FCD
:00000001FF

Листинг на АСМе:

;	ТАЙМЕР ТОЧЕЧНОЙ СВАРКИ 
;--------------------------------------------
; by Yampolsky Mark, Fryazino, march 2009
;--------------------------------------------
list	  p=12F675
#include <p12F675.inc>
errorlevel  -302
;***********************************************
; 8 пин общий
; 7 пин CIN+[AN0][GP0] - вход синхронизации с сетью
; 6 пин AN1[GP1] - вход управл.временем импульса
; 5 пин GP2 - выход управл.драйвером оптрона
; 4 пин MCLR
; 3 пин AN3[GP4] - выбор диапазона времени
; 2 пин GP5 - пуск
; 1 пин питание +U (5 вольт)
;***********************************************
cblock	0x20
	time
	T0
	temp0
	temp1
	flag
	w_temp
	status_temp
endc


;-----------------------------------------------
__CONFIG   _CP_OFF & _CPD_OFF & _BODEN_OFF & _MCLRE_ON & _WDT_OFF & _PWRTE_ON & _INTRC_OSC_NOCLKOUT 
;***********************************************
org	0x00
	nop
	goto		main
;-----------------------------------------------
org	0x04
	movwf		w_temp
	movf		STATUS,w
	movwf		status_temp
	btfsc		INTCON,T0IF	; семафор таймер/компаратор
	goto		int_T0
int_compar	movlw		b'01000000'	; маска на выход компаратора
	andwf		CMCON,w
	btfss		STATUS,Z	; если выход компаратора не 0
	goto		no		; идем на пропуск
	movf		time,w	; иначе код времени
	call		tab_counter	; преобразуем в уст.счетчика прерыв.
	movwf		T0		; и загружаем в этот счетчик

	movlw		.25		; задержка в 80 мкс - подгонка под нулевой переход
	addlw		0xFF
	btfss		STATUS,Z
	goto		$-2


	movf		time,w
	call		tab_preset	; преобразуем в предустан.TMR0
	movwf		TMR0		; загружаем в TMR0
	bsf		GPIO,2	; включаем оптрон
	bcf		INTCON,T0IF	; гасим флаг таймера
	bsf		INTCON,T0IE	; разрешаем прерывания от таймера
	bsf		STATUS,RP0
	bcf		PIE1,CMIE	; запрещаем прерывания от компаратора
	bcf		STATUS,RP0
no		bcf		PIR1,CMIF	; гасим флаг компаратора
	goto		exit		; выходим из обработчика
int_T0	decfsz	T0,f		; декрементируем счетчик прерываний
	goto		$+4		; если не ноль в счетчике, то выходим
	bcf		GPIO,2	; иначе выключаем оптрон
	bcf		flag,1	; сбрасываем флаг исполнения
	bcf		INTCON,T0IE	; запрещаем прерывание от таймера
	bcf		INTCON,T0IF	; сбрасываем флаг таймера
exit		movf		status_temp,w; выходим из обработчика
	movwf		STATUS
	swapf		w_temp,f
	swapf		w_temp,w
	retfie
;-----------------------------------------------
tab_preset	clrf		PCLATH
	addwf		PCL,f
	retlw		.230
	retlw		.203
	retlw		.177
	retlw		.150
	retlw		.124
	retlw		.97
	retlw		.71
	retlw		.44
	retlw		.18
	retlw		.247
	retlw		.221
	retlw		.194
	retlw		.168
	retlw		.141
	retlw		.115
	retlw		.88
	retlw		.62
	retlw		.35
	retlw		.9
	retlw		.238
	retlw		.212
	retlw		.185
	retlw		.159
	retlw		.132
	retlw		.106
	retlw		.79
	retlw		.53
	retlw		.26
	retlw		.0
	retlw		.229
;-----------------------------------------------
tab_counter	clrf		PCLATH
	addwf		PCL,f
	retlw		.7
	retlw		.13
	retlw		.19
	retlw		.25
	retlw		.31
	retlw		.37
	retlw		.43
	retlw		.49
	retlw		.55
	retlw		.62
	retlw		.68
	retlw		.74
	retlw		.80
	retlw		.86
	retlw		.92
	retlw		.98
	retlw		.104
	retlw		.110
	retlw		.116
	retlw		.123
	retlw		.129
	retlw		.135
	retlw		.141
	retlw		.147
	retlw		.153
	retlw		.159
	retlw		.165
	retlw		.171
	retlw		.177
	retlw		.184
;===============================================
main		clrf		time		; очищаем интервал
	clrf		T0		; очищаем счетчик прерываний
	clrf		temp0
	clrf		temp1
	clrf		flag
	clrf		INTCON
	movlw		b'00011110'
	movwf		CMCON
	clrf		GPIO
	bsf		STATUS,RP0
	clrf		PIE1
	movlw		b'00111011'
	movwf		TRISIO
	movlw		b'00100000'
	movwf		WPU
	movlw		b'00011011'
	movwf		ANSEL
	call		0x3FF
	movwf		OSCCAL
	movlw		b'10100001'
	movwf		VRCON
	movlw		b'00000101'
	movwf		OPTION_REG
	bcf		STATUS,RP0
	movlw		b'00000101'
	movwf		ADCON0
	bsf		INTCON,PEIE
;-----------------------------------------------
adc		bsf		ADCON0,CHS1	; АЦП подключаем к селектору диапазона
	nop
	nop
	nop
	nop
	nop
	nop
	nop
	nop
	nop
	nop
	bsf		ADCON0,GO
	btfsc		ADCON0,GO
	goto		$-1
	call		sw_band	; преобразуем в код диапазона
	movwf		time
	bcf		ADCON0,CHS1	; АЦП подключаем к селектору интервала
	nop
	nop
	nop
	nop
	nop
	nop
	nop
	nop
	nop
	nop
	bsf		ADCON0,GO
	btfsc		ADCON0,GO
	goto		$-1
	call		sw_time	; преобразуем в код интервала
	addwf		time,f	; получаем полный код длительности импульса
	btfsc		GPIO,5	; проверяем нажатую кнопку "пуск"
	goto		adc		; если не нажата возвращаемся на ввод интервала
	btfsc		flag,0	; иначе,если флаг=0, кнопка нажата только что
	goto		wait_butt	; иначе кнопка не отпущена после исполнения
	bsf		flag,0	; уст.флага нажатого пуска
	bsf		flag,1	; уст.флага исполнения
	movf		CMCON,f	; чтение компаратора для устран.несоответствия
	bcf		PIR1,CMIF	; сбрасываем флаг компаратора
	bsf		STATUS,RP0
	bsf		PIE1,CMIE	; разрешаем прерывания от компаратора
	bcf		STATUS,RP0
	bsf		INTCON,GIE
	btfsc		flag,1	; ждем пока флаг исполнения не сброшен
	goto		$-1
;-----------------------------------------------
wait_butt	btfss		GPIO,5
	goto		$-1
	movlw		0x0E		; антидребезг
	movwf		temp0
	clrf		temp1
	decfsz	temp1,f
	goto		$-1
	decfsz	temp0,f
	goto		$-4
	btfss		GPIO,5
	goto		$-8
	bcf		flag,0
	goto		adc
;-----------------------------------------------
sw_time	movlw		.247
	subwf		ADRESH,w
	btfsc		STATUS,C
	retlw		.9
	movlw		.230
	subwf		ADRESH,w
	btfsc		STATUS,C
	retlw		.8
	movlw		.213
	subwf		ADRESH,w
	btfsc		STATUS,C
	retlw		.7
	movlw		.196
	subwf		ADRESH,w
	btfsc		STATUS,C
	retlw		.6
	movlw		.179
	subwf		ADRESH,w
	btfsc		STATUS,C
	retlw		.5
	movlw		.162
	subwf		ADRESH,w
	btfsc		STATUS,C
	retlw		.4
	movlw		.145
	subwf		ADRESH,w
	btfsc		STATUS,C
	retlw		.3
	movlw		.128
	subwf		ADRESH,w
	btfsc		STATUS,C
	retlw		.2
	movlw		.111
	subwf		ADRESH,w
	btfsc		STATUS,C
	retlw		.1
	retlw		.0
;-----------------------------------------------
sw_band	movlw		.128
	subwf		ADRESH,w
	btfsc		STATUS,C
	retlw		.20
	movlw		.111
	subwf		ADRESH,w
	btfsc		STATUS,C
	retlw		.10
	retlw		.0
;-----------------------------------------------
END

фото устройства:

9669872687c4.jpg

b9669a767a07.jpg

Изменено пользователем my504
0

戦う前に相手のベルトの色に注目

Ссылка на комментарий
Поделиться на другие сайты
  • 4 недели спустя...

Особенности хранения литиевых аккумуляторов и батареек

Потеря емкости аккумулятора напрямую зависит от условий хранения и эксплуатации. При неправильном хранении даже самый лучший литиевый источник тока с превосходными характеристиками может не оправдать ожиданий. Технология, основанная на рекомендациях таких известных производителей литиевых источников тока, как компании FANSO и EVE Energy, поможет организовать правильный процесс хранения батареек и аккумуляторов. Подробнее>>

Реклама: АО КОМПЭЛ, ИНН: 7713005406, ОГРН: 1027700032161

draf Стажер

draf

Опубликовано
  • Автор
Опубликовано

Вот,почти собраное в кучу устройство (с временем голяк).

Бальшая благодарность my504 за разработку и изготовление "мозга" все этого!!!!

post-76695-1241029627_thumb.jpg

0
Ссылка на комментарий
Поделиться на другие сайты
  • 2 недели спустя...

Выбираем схему BMS для корректной работы литий-железофосфатных (LiFePO4) аккумуляторов

 Обязательным условием долгой и стабильной работы Li-FePO4-аккумуляторов, в том числе и производства EVE Energy, является применение специализированных BMS-микросхем. Литий-железофосфатные АКБ отличаются такими характеристиками, как высокая многократность циклов заряда-разряда, безопасность, возможность быстрой зарядки, устойчивость к буферному режиму работы и приемлемая стоимость. Но для этих АКБ, также как и для других, очень важен контроль процесса заряда и разряда, а специализированных микросхем для этого вида аккумуляторов не так много. Инженеры КОМПЭЛ подготовили список имеющихся микросхем и возможных решений от разных производителей. Подробнее>>

Реклама: АО КОМПЭЛ, ИНН: 7713005406, ОГРН: 1027700032161

Присоединяйтесь к обсуждению

Вы можете написать сейчас и зарегистрироваться позже. Если у вас есть аккаунт, авторизуйтесь, чтобы опубликовать от имени своего аккаунта.
Примечание: Ваш пост будет проверен модератором, прежде чем станет видимым.

Гость
Unfortunately, your content contains terms that we do not allow. Please edit your content to remove the highlighted words below.
Ответить в этой теме...

×   Вставлено с форматированием.   Восстановить форматирование

  Разрешено использовать не более 75 эмодзи.

×   Ваша ссылка была автоматически встроена.   Отображать как обычную ссылку

×   Ваш предыдущий контент был восстановлен.   Очистить редактор

×   Вы не можете вставлять изображения напрямую. Загружайте или вставляйте изображения по ссылке.

Загрузка...
×
 Поделиться
Перейти к списку тем

  • Последние посетители   0 пользователей онлайн

    • Ни одного зарегистрированного пользователя не просматривает данную страницу
×
×
  • Создать...